//ink pen
#declare pov_pen =
union {
  cylinder { <0,0,0> <4.875,0,0> 0.14 texture { whiteplastic } }
  cone { <0,0,0> 0.14 <-0.125,0,0> 0.12 texture { blueplastic } }
  cone { <-0.125,0,0> 0.12 <-0.375,0,0> 0.09 texture { blueplastic } }
  difference {
    sphere { <4.71,0,0> 0.22 }
    box { <4.875,-1,-1> <4,1,1> }
    texture { blueplastic }
  }
  cylinder { <-0.375,0,0> <-0.44,0,0> 0.07 texture { dkbeigepaint } }
  cone { <-0.44,0,0> 0.07 <-0.63,0,0> 0.05 texture { dkbeigepaint } }
  cone { <-0.63,0,0> 0.045 <-0.73,0,0> 0.015 texture { T_Gold_2B } }
  text { ttf "cyrvetic.ttf", "POV round stik med/moy USA", 0.02 0
    scale 0.12 translate <1.5,-0.05,-0.14>
    texture { blackplastic } }
  text { ttf "povlogo.ttf", "P", 0.02 0
    scale 0.13 translate <1.3,-0.08,-0.14>
    texture { blackplastic } }
}

//ink pen cap
#declare pov_pen_cap =
union {  //bic pen cap
  //the origin is mid-cap, so that when combined with the pen, the
  //pen is closed
  difference {
    union {
      cylinder { <0.125,0,0> <0.5,0,0> 0.18 }
      torus { 0.18 0.017 rotate 90*z translate <0.125,0,0> }
      cone { <0.125,0,0> 0.18 <-1.0625,0,0> 0.15 }
      cone { <-1.0625,0,0> 0.14 <-1.0925,0,0> 0.10 }
      difference {
        box { <0,-0.1,-0.08> <1.275,0.09,0.08> }
	box { <0,-1,-1> <1,1,1> rotate -45*y translate 1.29*x }
	box { <0,-1,-1> <1,1,1> rotate 45*y translate 1.29*x }
	box { <-1,-1,-1> <0,1,1> rotate -45*z }
	box { <-1,-1,0> <2,1,1> rotate -27*x translate 0.08*z }
	box { <-1,-1,-1> <2,1,0> rotate 27*x translate -0.08*z }
	translate <0.125,0.17,0>
      }
    }
    cylinder { <0.125,0,0> <0.6,0,0> 0.16 }
    cone { <0.126,0,0> 0.13 <-1.05,0,0> 0.11 }
    cone { <0.5,0,0> 0.15 <1.5,0,0> 0.21 }
    difference {
      cylinder { <-1.1,0,0> <-1,0,0> 0.09 }
      cylinder { <-1.1,0,0> <-1,0,0> 0.07 }
      box { <-1.07,0,-0.02> <-1,0.2,0.02> rotate 180*x }
      box { <-1.07,0,-0.02> <-1,0.2,0.02> rotate 60*x }
      box { <-1.07,0,-0.02> <-1,0.2,0.02> rotate 300*x }
    }
  }
  texture { blueplastic }
}