#declare purpleplastic = texture { pigment { color rgb <0.8 0.0 0.8> } finish { specular 0.5 diffuse 0.6 } }
#declare limegreenplastic = texture { pigment { color rgb <0.7 1.0 0.0> } finish { specular 0.5 diffuse 0.6 } }

#declare noseman =
union {
  difference {
    union {
      cylinder { <0,0,0> <0,0,-0.375> 0.8 }
      cylinder { <0,0,0> <0,0,-0.335> 0.83 }
      torus { 0.8 0.03 rotate 90*x translate <0,0,-0.345> }
    }
    //smile
    difference {
      torus { 0.65 0.07 rotate 90*x translate -0.375*z }
      box { <-1,0,-1> <1,1,1> rotate 45*z }
      box { <-1,0,-1> <1,1,1> rotate -45*z }
    }
    sphere { <0,-0.65,-0.375> 0.07 rotate 45*z }
    sphere { <0,-0.65,-0.375> 0.07 rotate -45*z }
  }
  //eyes
  sphere { <-0.375,0.375,-0.33> 0.2 texture { limegreenplastic } }
  sphere { <0.375,0.375,-0.33> 0.2 texture { limegreenplastic } }
  //nose
  difference {
    union {
      box { <-0.2,-0.45,0> <0.2,0.77,-0.875> }
      box { <-0.2,-0.2,0> <0.2,0.77,-1.1> }
      cylinder { <-0.2,-0.2,-0.875> <0.2,-0.2,-0.875> 0.25 }
    }
    box { <-2,-2,-2> <0,2,2> rotate -2*z rotate -3*y translate <-0.1,0,0> }
    box { <2,-2,-2> <0,2,2> rotate 2*z rotate 3*y translate <0.1,0,0> }
    box { <-2,-2,-2> <2,2,0> rotate 40*x translate <0,0,-1.02> }
  }
  texture { purpleplastic }
}