#declare chrome = texture { pigment { color rgb <0.6,0.6,0.6> } finish { specular 0.5 diffuse 0.5 reflection 0.2 roughness 0.005 metallic } }
#declare magnetred = texture { pigment { color rgb <0.7,0,0> } finish { diffuse 0.6 specular 0.2 } }

#declare horseshoe_magnet =
union {
  difference {
    union {
      cylinder { <-0.157,0,0> <0.157,0,0> 0.5625 }
      box { <-0.157,0,-0.55> <0.157,0.45,0.55> }
    }
    box { <-1,0.43,-1> <1,1,1> texture { chrome } }
    box { <-0.2,0,0> <0.2,1,0.1875> rotate 8*x translate -0.1875*z }
    box { <-0.2,0,-0.1875> <0.2,1,0> rotate -8*x translate 0.1875*z }
    box { <-0.2,0,0> <0.2,1,0.1875> rotate 18*x translate -0.78*z }
    box { <-0.2,0,-0.1875> <0.2,1,0> rotate -18*x translate 0.78*z }
    cylinder { <-0.2,0,0> <0.2,0,0> 0.1875 }
    sphere { <0.157,-0.4,0> 0.1 }
    sphere { <0,0,0> 0.09 scale <0.6,1,1> translate <-0.157,-0.4,0> rotate 45*x }
    sphere { <0,0,0> 0.09 scale <0.6,1,1> translate <-0.157,-0.4,0> rotate -45*x }
    difference {
      torus { 0.4 0.09 rotate 90*z scale <0.6,1,1> }
      box { <-2,-2,0> <2,2,2> }
      box { <-2,0,-2> <2,2,2> }
      rotate -45*x
      translate <-0.157,0,0>
    }
  }
  text { ttf "povlogo.ttf", "P", 1 0
    rotate -90*y rotate 180*x scale 0.12 translate <0.13,-0.34,0.04> }
  //text { ttf "cyrvetic.ttf", "G", 1 0
  //  rotate -90*y rotate 180*x scale 0.12 translate <0.13,-0.36,0.04> }

  text { ttf "cyrvetic.ttf", "E", 1 0
    rotate 90*y rotate 180*x scale 0.12 translate <-0.14,-0.36,-0.04> rotate 42*x }
  text { ttf "cyrvetic.ttf", "N", 1 0
    rotate 90*y rotate 180*x scale 0.12 translate <-0.14,-0.36,-0.04> rotate 28*x }
  text { ttf "cyrvetic.ttf", "G", 1 0
    rotate 90*y rotate 180*x scale 0.12 translate <-0.14,-0.36,-0.04> rotate 14*x }
  text { ttf "cyrvetic.ttf", "L", 1 0
    rotate 90*y rotate 180*x scale 0.12 translate <-0.14,-0.36,-0.03> }
  text { ttf "cyrvetic.ttf", "A", 1 0
    rotate 90*y rotate 180*x scale 0.12 translate <-0.14,-0.36,-0.04> rotate -14*x }
  text { ttf "cyrvetic.ttf", "N", 1 0
    rotate 90*y rotate 180*x scale 0.12 translate <-0.14,-0.36,-0.04> rotate -28*x }
  text { ttf "cyrvetic.ttf", "D", 1 0
    rotate 90*y rotate 180*x scale 0.12 translate <-0.14,-0.36,-0.04> rotate -42*x }
  texture { magnetred }
  normal {
    crackle 1
    scale 0.03
  }
  rotate 90*x
  translate <0,0,-0.43>
}